[Delila]

Idézet: kroozo - Dátum: 2010. 03. 24. 14:47

Diagramnak valahogy meg lehet hatarozni dinamikusan a tartomanyat?

Próbáld meg letölteni a PC Wordl című folyóirat 2008. májusi számát. Abban (a 108. oldalon) Weisz Tamás "Dinamikus grafikonok" című írásában választ kapsz a kérdésedre. Lépésről-lépésre, jól követhetően leírja, hogy kell elkészíteni.

[kroozo]

Idézet: Delila - Dátum: 2010. 03. 24. 18:20

Próbáld meg letölteni a PC Wordl című folyóirat 2008. májusi számát. Abban (a 108. oldalon) Weisz Tamás "Dinamikus grafikonok" című írásában választ kapsz a kérdésedre. Lépésről-lépésre, jól követhetően leírja, hogy kell elkészíteni.

Koszonom, meglesem!

[debaj]

Sziasztok! Excel 2007-ben hol lehet kikapcsolni az olyan faszságokat, mint például azt, hogy a 15,6-ot automatikusan átírja június 15-re?

[Lacy1]

Sziasztok!

Egy nagy kérdésem lenne pontosan 594.731 sornyi és 2 oszlopnyi, ugyanis ennyi adatot kéne rendeznem vagyis napi átlagot számolnom belőle.
A fő kérdés az azonban az, hogy tudom-e valamilyen szinten automatizáltatni az egy napon mért adatokból az átlag számítást, mert az a baj, hogy egy napon van úgy hogy csak 1 adatvan de van úgy hogy pl. 13, tehát változó az adatmennyiség és még nem is mindegyik napra van(nak) mérési eredmények, ezek az adatmérések még ráadásul több is mint egy évnyi adat.
Tehát valahogy lehet e egy kicsit automatizáltatni, mert így elég lassan megy, ha egyesével jelölgetem ki az átlag számítást!

Megpróbáltam elindulni azon a vonalon, hogy a nap számát kiírtam egy oszlopba kölön, de innen nem jutottam sehogy dülőre, megjegyzem lehet hogy nem is így kéne elindulnom, dehát jobb ötletem nem volt..

Ha tudtok légyszi segítsetek nekem ebben, előre is köszönöm nektek.

Köszönettel: Lacy

[Delila]

Lacy1

Ha a dátumok az A oszlopban vannak, a hozzájuk tartozó értékek a B-ben, akkor (címsort feltételezve) a C2 képlete:
=SZUMHA(A:A;A2;B:B)/DARABTELI(A:A;A2)
Ezt a képletet másold le végig az adataid mellé.

Szerkesztette: Delila 2010. 04. 19. 10:32 -kor

[Lacy1]

Szia Delila!

Először is köszi a segítséged, de nem teljesen erre gondoltam.
Na akkor mégegyszer érthetőbben megpróbálom elmondani, és inkább képként csatolni is
Tehát az egy napon mért adatokból több van pl egy mérés készült 2010.01.12 8:13:23-kor meg egy másik 2010.01.12 12:34:56-kor, és most ezekből az adatokból szertetnék átlagot, de csak az egy napon készültekből.

Csatolt fájl:

•  Kép1.JPG (99,64K)
  Letöltések:: 25

[Delila]

Szia Lacy!

Akkor egy segédoszlopot beiktatása segít, ez legyen az E oszlop.
Az E5 képlete: =DÁTUM(ÉV(A5);HÓNAP(A5);NAP(A5))
Az F5-é pedig: =SZUMHA(E:E;E5;D:D)/DARABTELI(E:E;E5)

[Lacy1]

Idézet: Delila - Dátum: 2010. 04. 19. 11:44

Szia Lacy!

Akkor egy segédoszlopot beiktatása segít, ez legyen az E oszlop.
Az E5 képlete: =DÁTUM(ÉV(A5);HÓNAP(A5);NAP(A5))
Az F5-é pedig: =SZUMHA(E:E;E5;D:D)/DARABTELI(E:E;E5)

Köszönöm szépen!!!

Működik pontosan erregondoltam.

De mégegykérdést engedj meg, hogy mi módon tudok olyat csinálni - mert ugye most ugyanaz az eredmény megvan többször - , hogy szűdök belőle de úgy hogy egy nap átlagai csak egyszer legyenek meg, tehát egy nap csak egyszer szerepeljen.

Köszönettel: Lacy

[Delila]

Az E5 képlete marad, az F5-é:
=HA(DARABTELI($E$5:$E5;E5)=1;SZUMHA(E:E;E5;D:D)/DARABTELI($E$5:$E$500000;E5);"")

Ügyelj a $ jelekre! Az 500000 helyett az alsó sorod sorszámát írd be, de jó, ha még nagyobb értéket adsz.

[GP#2]

Idézet: Delila - Dátum: 2010. 04. 19. 15:15

Az E5 képlete marad, az F5-é:
=HA(DARABTELI($E$5:$E5;E5)=1;SZUMHA(E:E;E5;D:D)/DARABTELI($E$5:$E$500000;E5);"")

Ügyelj a $ jelekre! Az 500000 helyett az alsó sorod sorszámát írd be, de jó, ha még nagyobb értéket adsz.

Eddig egy másik fórum zargattalak időnként dtpeter néven, de miután ez a téma itt merült fel, hát idekívánkozik: Hatalmas köszönet a fentiekért!

Egy olyan problémát oldottál meg nekem ami már régóta foglalkoztatott, és azt hittem, hogy makró nélkül nem is lehet megcsinálni. Az alap egyébként nagyon hasonló volt, annyival megbolondítva, hogy nekem minden nap mellé kell számolni az adott hónap értékeinek átlagát. Így beiktattam egy plusz oszlopot, amiben az =ÉV(A1)*100+HÓNAP(A1) - ami mondjuk a márciusi dátumokra 201003-at hoz eredményül - szerepel, és ezzel kiegészítve már vígan megy a dolog

Arra nem tudsz esetleg valami megoldást, hogy ha mondjuk egy képletben (A2:A5000) tartománnyal akarok dolgozni, akkor az 5000-et egy másik cellából hozza? Arra lenne jó, hogy ne kelljen feleslegesen nagy tartományokat megadni a képleteimben, mert úgy vettem észre, hogy eléggé belassítja a dolgokat, még akkor is, ha amúgy üres a tartomány egy része. Az adatbázis viszont folyamatosan nő, és ha mondjuk egy DARAB függvénnyel kiíratnám, hogy éppen hány hasznos sor van, akkor csak ezzel a tartománnyal kéne számolnia a programnak. Próbálkoztam az ÖSSZEFŰZ függvénnyel, ami nem igazán vezetett eredményre, de hátha erre is van valami elegáns ötleted

[Delila]

Nem kell külön cellában megadni a darabszámot, az INDIREKT függvény segít.

=SZUM(INDIREKT("A2:A"&DARAB2(A:A)))

Az ÖSSZEFŰZ függvény egyszerűbb változata, ha magát a függvényt nem írod ki. Az =ÖSSZEFŰZ(A1;B1) helyett tökéletes az =A1&B1, itt is így alkalmaztam. A DARAB2(A:A) megadja az oszlopban lévő kitöltött cellák darabszámát (tekintet nélkül arra, hogy a cellák szöveget, dátumot, számot, vagy éppen logikai értéket tartalmaznak-e), ami az utolsó sorral egyenlő.

Vegyük, hogy az E1 tartalma B, az F1 pedig 20. Az =INDIREKT(E1&F1)a B20-as cella értékét hozza, vagyis egy szövegesen megadott hivatkozást ad. A fenti képletben az összefűzés első tagja az "A2:A", a második a DARAB2 eredménye.

Ha mégis külön cellában (pl. G1-ben) akarod megadni az utolsó sor számát, akkor az összegző képlet
=SZUM(INDIREKT("A2:A"&G1))

Az indirekt függvénnyel más lapon lévő adatra is hivatkozhatsz: =INDIREKT("Munka3!A15"), vagy ha az aktuális lapon az F1 értéke A15: =INDIREKT("Munka3!"&F1). Ezt aztán variálhatod kedved és igényed szerint. Az E1 értéke legyen Munka3, az F1 legyen A, a G1 pedig 15. A képlet: =INDIREKT(E1&"!"&F1&G1)

[GP#2]

Idézet: Delila - Dátum: 2010. 04. 21. 07:37

Nem kell külön cellában megadni a darabszámot, az INDIREKT függvény segít.

=SZUM(INDIREKT("A2:A"&DARAB2(A:A)))

...

Köszönöm szépen! Ki is próbáltam, és természetesen tökéletesen működik, most már csak azt kell letesztelnem, hogy gyorsaságban jelent-e különbséget, ha beépítem a függvénybe a DARAB2 részt, vagy külön cellába érdemesebb rakni és hivatkozni rá. Mindenesetre megint tanultam valami hasznosat, örök hála érte

[Delila]

Nagyon szívesen. A teszt eredménye engem is érdekel, írd meg!

[debaj]

Idézet: Lacy1 - Dátum: 2010. 04. 19. 14:22

Köszönöm szépen!!!

Működik pontosan erregondoltam.

De mégegykérdést engedj meg, hogy mi módon tudok olyat csinálni - mert ugye most ugyanaz az eredmény megvan többször - , hogy szűdök belőle de úgy hogy egy nap átlagai csak egyszer legyenek meg, tehát egy nap csak egyszer szerepeljen.

Köszönettel: Lacy

Ha már különválasztottad a dátumot az időtől, akkor a pivot tábla lesz a te nagy barátod.

Az automatikusan dátumra váltó ökörség kiirtására nincs valakinek ötlete?

Szerkesztette: debaj 2010. 04. 23. 10:17 -kor

[GP#2]

Idézet: Delila - Dátum: 2010. 04. 22. 06:45

Nagyon szívesen. A teszt eredménye engem is érdekel, írd meg!

Az elmúlt 1,5 órában ezzel vacakoltam, de csak minimálisan lettem okosabb, már ha egyáltalán. Szóval vettem egy 6000 soros adathalmazt (dátum, összeg, év&hónap, adott hónap átlaga), ahol az izgalmas rész adott hónap átlagának kiszámításánál van, a korábbi hozzászólások módszerével. Aztán elkezdtem nyomozni, hogy melyik a gyorsabb:

1, a DARAB2 függvény külön cellában van, egyszer számolja ki, és a hatezer sor mindegyikében az indirekt függvénnyel erre a cellára mutatok rá
2, a DARAB2 függvény minden egyes cellában kiszámolásra kerül, méghozzá háromszor: a SZUMHA függvény kétszer igényli, aztán osztjuk a napok számával, amit egy DARABTELI függény számít
3, próbálkoztam még egy másik variácóval, kicsit számításigényesebb, de a DARAB2-nél jobban kezeli, ha van véletlenül üres sor: HOL.VAN(MAX(A2:10000);A2:10000;1)+1. Ezt szintén egy cellában rögzítve, majd minden sorba beépítve is megnéztem.

Érdekes módon nem voltak óriási eltérések, a leggyorsabb két variáció az volt, amikor külön cellában volt tárolva a sorok száma (mindegy, hogy DARAB2, vagy a HOL.VAN kezdetű). Ezzel kb. 11 mp alatt számolta ki az eredményt.

A második helyezett a beépített DARAB2, kb. 12 mp-el, a harmadik pedig a beépített HOL.VAN kezdetű, kb. 13 mp-el.

Alighanem másfelé kell indulnom, ha optimalizálni akarok, mert ez az 1-2 mp. nem tűnik lényegi különbségnek. Az már sokkal inkább, hogy hány sor van, amiből aztán ide-oda kereshet (az "éles" táblázatomban 5 FKERES függvény gyűjti az adatokat egy 4-8000 soros táblázatból ide a havi átlag számító lapra, itt pár szempontot figyel, aztán innen meg visszaírja az átlagot és az egyéb kapott ereményeket a főtábla megfelelő soraiba, azaz ahhoz a hónaphoz tartozó összes sorhoz).
Szóval valahogy bontani kellene az időszakokat, akár úgy, hogy évente új excel táblát kezdek (amit nem szeretnék), vagy valahogy rá kell vennem az excelt, hogy csak a megfelelő helyről szedje az adatokat. Még ötletelek rajta, de most holnapig nem akarok excelt látni

[GP#2]

Idézet: debaj - Dátum: 2010. 04. 23. 11:15

Az automatikusan dátumra váltó ökörség kiirtására nincs valakinek ötlete?

Sajnos nincs, még a problémát sem sikerült reprodukálnom (nálam a 15,6-ot nem írja át június 15-re). Alapvetően a cellaformázásra gyanakszom, de akárhogy küzdöttem, sehogy sem jött elő ez a gond. Amit persze nem bánok, csak így segíteni sem tudok...

[Delila]

Mit szólsz a következőkhöz:

Az A oszlopban vannak az összefűzött dátumaid (201001-201012), B-ben az értékeid, és a márciusi adatokat akarod átlagolni.
E1-be beírod a keresett időszakot, jelenleg 201003-at.
E2 -> =HOL.VAN(E1;A:A;0)
F2 -> =HOL.VAN(E1+1;A:A;0)
Az átlag valahol egy cellában: =ÁTLAG(INDIREKT("B"&E2):INDIREKT("B"&F2-1))

Vagy:
F1:F12-ig rendre 201001; 201002 ... 201012
G1 -> =ÁTLAG(INDIREKT("B"&HOL.VAN(F1;A:A;0)):INDIREKT("B"&HOL.VAN(F1+1;A:A;0)-1)), ezt másolod G11-ig.
G12 -> =ÁTLAG(INDIREKT("B"&HOL.VAN(F12;A:A;0)):INDIREKT("B"&10000))
Ez állandóan mutatja a hónapok aktuális átlagát. A hibája, hogy amíg nincs a keresett dátumnál nagyobb, addig #HIÁNYZIK a visszatérési érték, amit egy HA függvénnyel ki lehet küszöbölni, ami viszont biztosan növeli az időt.
A HA függvény a G1-ben:
=HA(HIBÁS(HOL.VAN(F1+1;A:A;0));ÁTLAG(INDIREKT("B"&HOL.VAN(F1;A:A;0)):INDIREKT("B"&10000));
ÁTLAG(INDIREKT("B"&HOL.VAN(F1;A:A;0)):INDIREKT("B"&HOL.VAN(F1+1;A:A;0)-1)))

[Megfeleztem, mert csúnyán kilógott a sorból ]

Szerkesztette: Delila 2010. 04. 25. 07:11 -kor

[Delila]

Idézet: debaj - Dátum: 2010. 04. 23. 10:15

Az automatikusan dátumra váltó ökörség kiirtására nincs valakinek ötlete?

Mint GP#2 példája mutatja, a tizedes vesszővel beírt számra nem vált át dátum formátumra, a pontra igen. Ha módod van rá, a Windowsban a területi beállításoknál a számformátumot ennek megfelelően állítsd át.

[Lacy1]

Idézet: Delila - Dátum: 2010. 04. 19. 14:15

Az E5 képlete marad, az F5-é:
=HA(DARABTELI($E$5:$E5;E5)=1;SZUMHA(E:E;E5;D:D)/DARABTELI($E$5:$E$500000;E5);"")

Ügyelj a $ jelekre! Az 500000 helyett az alsó sorod sorszámát írd be, de jó, ha még nagyobb értéket adsz.

Sziasztok!

Ismét lenne egy kérdésem a múltkori átlagszámítással kapcsolatban. Most heti átlagokat kéne számolnom a múltkorihoz hasonlóan, tehát kiszedtem egy külön oszlopba a hetek számát és ezt a képletet ráírtam, ami látszólag működik is, de rossz átlagértéket ad vissza, mert több év adai vannak rögzítve és ugyebár mondjuk a 2-dik hét többször is előfordul és azt is hozzászámolja.

Erre szeretnék kérni tőletek megoldási ötletet.

Most a táblám a következő képp néz ki:
C oszlop dátumok, D oszlop pedig az értékek, amiből átlagot kéne számolnom.

Köszönettel:
Lacy1

[Delila]

Lacy1

Vegyük, hogy mint legutóbb, most is az 5. sorban kezdődnek az adataid.
E5-be: =ÉV(C5)&JOBB("0"&WEEKNUM(C5;2);2)
F5-be: =HA(DARABTELI($E$5:$E5;E5)=1;SZUMHA(E:E;E5;D:D)/DARABTELI(INDIREKT("$E$5:$E"&DARAB2(E:E)+4);E5);"")

A két cellát együtt kijelölve másold le az adataid mellé.
Ha nincs Weeknum függvényed (ami az adott évben a hét sorszámát adja meg), az Eszközök/Bővítménykezelőben kapcsold be az Analysis kezdetű bővítményeket.

Az E5-be elég az =ÉV(C5)&WEEKNUM(C5;2) képlet is, csak a szebb külső miatt tettem be a JOBB függvényt. A 10 alatti sorszámú hét az évszámmal összefűzve 5 jegyű lenne nélküle (pl. 20108), a JOBB függvénnyel 6 jegyű, mint a 10 fölöttiek (201008, 201012).

Az F5 képletében kiemeltem a +4-et. Ez 1-gyel kevesebb, mint ahányadik helyen kezdődnek az adataid. Ha most nem az 5. sorban kezdődnek, a +4 helyett a megfelelő értéket írd be. Pl. ha most a 2. sortól vannak adatok, akkor +1 legyen, ha az elsőben, akkor nem kell kiírni a +0-t. A DARAB2 képlet adja az utolsó kitöltött sor számát.